A	B
Дата	Количество прибавляемых дней
09.06.2007	3
=СЕГОДНЯ()	5
10.12.2008	54
Формула	Описание (результат)
=A2+B2	Прибавление 3 дней к 09.06.2007 (12.06.2007)
=A3+B3	Прибавление 5 дней к текущей дате (значение может меняться)
=A4+B4	Прибавление 54 дней к 12/10/2008 (02.02.2009)

Прибавление к дате определенного количества месяцев

Для выполнения этой задачи используются функции ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.

Пример листа

Этот пример можно скопировать на пустой лист

1

2
3
4

A	B
Дата	Количество прибавляемых месяцев
09.06.2007	3
02.09.2007	5
10.12.2008	25
Формула	Описание (результат)
=ДАТА(ГОД(A2);МЕСЯЦ(A2)+B2;ДЕНЬ(A2))	Прибавление 3 месяцев к 09.06.2007 (09.09.2007)
=ДАТА(ГОД(A3);МЕСЯЦ(A3)+B3;ДЕНЬ(A3))	Прибавление 5 месяцев к 02.09.2007 (02.02.2008)
=ДАТА(ГОД(A4);МЕСЯЦ(A4)+B4;ДЕНЬ(A4))	Прибавление 25 месяцев к 10.12.2008 (10.01.2011)

Описание функций

ДАТА

ГОД

МЕСЯЦ

ДЕНЬ

Прибавление к дате определенного количества лет

Для выполнения этой задачи используются функции ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.

Пример листа

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

1

2
3
4

A	B
Дата	Количество прибавляемых лет
09.06.2007	3
02.09.2007	5
10.12.2008	25
Формула	Описание (результат)
=ДАТА(ГОД(A2)+B2;МЕСЯЦ(A2);ДЕНЬ(A2))	Прибавление 3 лет к 09.06.2007 (09.06.2010)
=ДАТА(ГОД(A3)+B3;МЕСЯЦ(A3);ДЕНЬ(A3))	Прибавление 5 лет к 02.09.2007 (02.09.2012)
=ДАТА(ГОД(A4)+B4;МЕСЯЦ(A4);ДЕНЬ(A4))	Прибавление 25 лет к 10.12.2008 (10.12.2033)

Описание функций

ДАТА

ГОД

МЕСЯЦ

ДЕНЬ

Прибавление к дате определенного количества дней, месяцев и лет

Для выполнения этой задачи используются функции ДАТА, ГОД, МЕСЯЦ и ДЕНЬ.

Пример листа

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

1

2

A
Дата
09.06.2007
Формула	Описание (результат)
=ДАТА(ГОД(A2)+3;МЕСЯЦ(A2)+1;ДЕНЬ(A2)+5)	Прибавление 3 лет, 1 месяца и 5 дней к 09.06.2007 (14.07.2010)
=ДАТА(ГОД(A2)+1;МЕСЯЦ(A2)+7;ДЕНЬ(A2)+5)	Прибавление 1 года, 7 месяцев и 5 дней к 09.06.2007 (14.01.2009)

Приведенная выше формула использует следующие аргументы.

Формула для прибавления дат

1 --- начальная_дата: дата или ссылка на ячейку, содержащую дату

2 --- прибавляемые_годы: количество прибавляемых лет

3 --- прибавляемые_месяцы: количество прибавляемых месяцев

4 --- прибавляемые_дни: количество прибавляемых дней

Описание функций

ДАТА

ГОД

МЕСЯЦ

ДЕНЬ

Прибавление времени

Для времени, введенного в стандартном формате времени (часы : минуты : секунды)

Для работы этого способа необходимо, чтобы значение часов не превышало 23, а значения минут и секунд не превышали 59.

Пример листа

1

2
3
4
5
6

A
Отработанные часы
1:35
8:30
3:00
4:15
8:00
Формула	Описание (результат)
=СУММ(A2:A5)	Сумма отработанных часов, если итоговое значение меньше суток (17:20)
=СУММ(A2:A6)*24	Сумма отработанных часов, если итоговое значение больше суток (25,33333)

Примечания

Чтобы просмотреть вторую формулу в виде числа, выделите содержащую ее ячейку и выберите в меню Формат команду Ячейки. На вкладке Число выберите в списке Числовые форматы вариант Общий.
Если прибавляемое время включает секунды, выберите формат ячейки, отображающий секунды. Выделите ячейку и выберите в меню Формат команду Ячейки. На вкладке Число выберите в списке Числовые форматы вариант Время.

Описание функций

СУММ

Для времени, введенного в виде числа, обозначающего отдельную единицу времени

Для работы в формуле с единицами времени, такими как час или минута, используется функция ВРЕМЯ.

Пример листа

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

1

2
3
4

A	B	C
Время	Описание	Значение
10:35:00	Часы	2
10:35:00	Минуты	10
10:35:00	Секунды	30
Формула	Описание (результат)
=A2+ВРЕМЯ(C2;0;0)	Прибавление 2 часов к заданному выше времени (12:35:00)
=A3+ВРЕМЯ(0;C3;0)	Прибавление 10 минут к заданному выше времени (10:45:00)
=A4+ВРЕМЯ(0;0;C4)	Прибавление 30 секунд к заданному выше времени (10:35:30)

Описание функций

ВРЕМЯ

Вычисление разности двух дат

Вычисление количества дней между двумя датами

Для выполнения этой задачи используется оператор вычитания (-) или функция ЧИСТРАБДНИ.

Если данная функция недоступна, установите и загрузите надстройку «Пакет анализа».

Пример листа

1

2
3

A
Дата
08.06.2007
20.06.2007
Формула	Описание
=A3-A2	Количество дней между двумя датами (12)
=ЧИСТРАБДНИ(A2;A3)	Количество рабочих дней между двумя датами (9)

Примечание. Чтобы просмотреть даты в виде чисел, выделите ячейку и выберите в меню Формат команду Ячейки. На вкладке Число выберите в списке Числовые форматы вариант Числовой.

Описание функций

ЧИСТРАБДНИ

Вычисление количества месяцев между двумя датами

Для выполнения этой задачи используются функции МЕСЯЦ и ГОД.

Пример листа

1

2
3
4

A
Дата
09.06.2007
02.09.2007
10.12.2008
Формула	Описание (результат)
=МЕСЯЦ(A3)-МЕСЯЦ(A2)	Количество месяцев между двумя датами, относящимися к одному году (3)
=(ГОД(A4)-ГОД(A3))*12+МЕСЯЦ(A4)-МЕСЯЦ(A3)	Количество месяцев между двумя датами, относящимися к разным годам (15)

Описание функций

МЕСЯЦ

ГОД

Вычисление количества лет между двумя датами

Для выполнения этой задачи используется функция ГОД.

Пример листа

1

2
3

A
Дата
09.06.2007
04.06.2010
Формула	Описание (результат)
=ГОД(A3)-ГОД(A2)	Количество лет между двумя датами (3)

Примечания

Чтобы просмотреть даты в виде чисел, выделите ячейку и выберите в меню Формат команду Ячейки. На вкладке Число выберите в списке Числовые форматы вариант Числовой.
Из более ранней даты нельзя вычитать более позднюю дату, в противном случае в ячейке будет отображаться ошибка ####.

Описание функций

ГОД

Вычисление разницы во времени

Для представления результата в стандартном формате времени (часы : минуты : секунды)

Для вычисления разницы во времени используется оператор вычитания (-), а для форматирования времени — функция ТЕКСТ.

Значение часов не должно превышать 23, а значения минут и секунд не должны превышать 59.

Пример листа

1

2

A	B
Начальное время	Конечное время
09.06.2007 10:35	09.06.2007 15:30
Формула	Описание (результат)
=ТЕКСТ(B2-A2;"ч")	Количество часов между двумя значениями времени (4)
=ТЕКСТ(B2-A2;"ч:мм")	Количество часов и минут между двумя значениями времени (4:55)
=ТЕКСТ(B2-A2;"ч:мм:сс")	Количество часов, минут и секунд между двумя значениями времени (4:55:00)

Примечание. Формат времени и даты для отображения значения можно применить и без использования функции ТЕКСТ. Однако при совместном выборе формата вручную и использовании функции ТЕКСТ действие функции ТЕКСТ имеет более высокий приоритет.

Описание функций

ТЕКСТ

Для представления результата в какой-либо одной единице времени (120 минут)

Для выполнения этой задачи используются функции ЦЕЛОЕ, ЧАС, МИНУТЫ и СЕКУНДЫ.

Пример листа

1

2

A	B
Начальное время	Конечное время
09.06.2007 10:35	10.06.2007 15:30
Формула	Описание (результат)
=ЦЕЛОЕ((B2-A2)*24)	Общее количество часов между двумя значениями времени (28)
=(B2-A2)*1440	Общее количество минут между двумя значениями времени (1735)
=(B2-A2)*86400	Общее количество секунд между двумя значениями времени (104100)
=ЧАС(B2-A2)	Количество часов между двумя значениями времени, если разница не превышает 23 (4)
=МИНУТЫ(B2-A2)	Количество минут между двумя значениями времени, если разница не превышает 59 (55)
=СЕКУНДЫ(B2-A2)	Количество секунд между двумя значениями времени, если разница не превышает 59 (0)

Описание функций

ЦЕЛОЕ

ЧАС

МИНУТЫ

СЕКУНДЫ

Преобразование времени

Преобразование единиц времени

Для выполнения этой задачи используется функция ПРЕОБР.

Если данная функция недоступна, установите и загрузите надстройку «Пакет анализа».

Пример листа

1

2

А
Данные
6
Формула	Описание (результат)
=ПРЕОБР(A2;"day";"hr")	Преобразование 6 дней в часы (144)
=ПРЕОБР(A2;"hr";"mn")	Преобразование 6 часов в минуты (360)
=ПРЕОБР(A2;"yr";"day")	Преобразование 6 лет в дни (2191,5)

Примечание. При преобразовании года считается, что количество дней в году равно 365,25.

Описание функций

ПРЕОБР

Преобразование часов из стандартного формата времени (часы : минуты : секунды) в десятичное число.

Для выполнения этой задачи используется функция ЦЕЛОЕ.

Пример листа

1

2
3

А
Время
10:35:00
12:15:00
Формула	Описание (результат)
=(A2-ЦЕЛОЕ(A2))*24	Число часов с 0:00:00 (10,583333)
=(A3-ЦЕЛОЕ(A3))*24	Число часов с 0:00:00 (12,25)

Описание функций

ЦЕЛОЕ

Преобразование часов из десятичного числа в стандартный формат времени (часы : минуты : секунды).

Для выполнения этой задачи используется оператор деления (/) или функция ТЕКСТ.

Пример листа

1

2
3

А
Часы
10,5833
12,25
Формула	Описание (результат)
=ТЕКСТ(A2/24; "ч:мм")	Часов с 0:00:00 (10:35:00)
=ТЕКСТ(A3/24; "ч:мм")	Часов с 0:00:00 (12:15:00)

Примечание. Формат времени для отображения значения можно применить и без использования функции ТЕКСТ. Чтобы просмотреть число в формате времени, выделите ячейку и выберите в меню Формат команду Ячейки. На вкладке Число выберите в списке Числовые форматы вариант Время. Однако при совместном выборе формата вручную и использовании функции ТЕКСТ действие функции ТЕКСТ имеет более высокий приоритет.

Описание функций

ТЕКСТ

Подсчет дней перед датой

Для выполнения этой задачи используется функция СЕГОДНЯ.

Пример листа

1

2
3

А
Дата
01.01.2008
01.06.2007
Формула	Описание (результат)
=A2-СЕГОДНЯ()	Число дней с текущей даты до конца 2007 (Отличается)
=A2-A3	Число дней с 01.06.2007 до конца 2007 года (214)

Примечания

В первой формуле текущая используемая дата выставляется в соответствии с системными часами компьютера.
В последней формуле, чтобы отобразить дату в виде числа, выделите ячейку и выберите в меню Формат команду Ячейки. На вкладке Число выберите Числовой в списке Числовые форматы.

Описание функций

СЕГОДНЯ

Вставка дат в юлианском представлении

Выражение "юлианское представление дат" иногда используется для обозначения формата даты, в котором после текущего года стоит номер дня с начала года. Например, 1 января 2007 года соответствует значение 2007001, а 31 декабря 2007 года — значение 2003356. Имейте в виду, что это представление не связано с юлианским календарем.

Юлианское представление дат также обычно используется в астрономии, где даты отсчитываются с 1 января 4713 года до н. э.

Ввод текущей даты в юлианском представлении

Для выполнения этой задачи используются функции ТЕКСТ, СЕГОДНЯ и ДАТАЗНАЧ.

Пример листа

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

1

2
3

A	B
Формула	Описание (результат)
=ТЕКСТ(СЕГОДНЯ();"гг")&ТЕКСТ((СЕГОДНЯ()-ДАТАЗНАЧ("1.1."&ТЕКСТ(СЕГОДНЯ();"гг"))+1);"000")	Текущий день в юлианском представлении с двузначным обозначением года (значения могут быть разными)
=ТЕКСТ(СЕГОДНЯ();"гггг")&ТЕКСТ((СЕГОДНЯ()-ДАТАЗНАЧ("1.1."&ТЕКСТ(СЕГОДНЯ();"гг"))+1);"000")	Текущий день в юлианском представлении с четырехзначным обозначением года (значения могут быть разными)

Примечания

В качестве значения даты берется значение системных часов компьютера.
В приведенных выше формулах год начинается с 1 января (1.1). Чтобы преобразовать формулу для использования другой начальной даты, смените «1.1.» на требуемую дату.

Описание функций

ДАТАЗНАЧ

ТЕКСТ

СЕГОДНЯ

Преобразование даты в юлианское представление

Для выполнения этой задачи используются функции ТЕКСТ и ДАТАЗНАЧ.

Пример листа

1

2

A
Дата
23.6.2007
Формула	Описание (результат)
=ТЕКСТ(A2;"гг")&ТЕКСТ((A2-ДАТАЗНАЧ("1.1."&ТЕКСТ(A2;"гг"))+1);"000")	Приведенная выше дата в юлианском представлении с двузначным обозначением года (07174)
=ТЕКСТ(A2;"гггг")&ТЕКСТ((A2-ДАТАЗНАЧ("1.1."&ТЕКСТ(A2;"гг"))+1);"000")	Приведенная выше дата в юлианском представлении с четырехзначным обозначением года (2007174)

Примечание. В приведенных выше формулах год начинается с 1 января (1.1). Чтобы преобразовать формулу для использования другой начальной даты, смените «1.1.» на требуемую дату.

Описание функций

ДАТАЗНАЧ

ТЕКСТ

Преобразование даты в юлианское представление, используемое в астрономии

Эта формула работает только с датами после 01.03.1901 и в книгах, использующих систему отсчета дат с 1900 года.

Пример листа

1

2

A
Дата
23.06.2007
Формула	Описание (результат)
=A2+2415018,50	Первая приведенная выше дата в юлианском представлении, используемом в астрономии (2454274,50)

Примечание. Чтобы просмотреть дату в виде числа, выделите ячейку и выберите в меню Формат команду Ячейки. На вкладке Число выберите в списке Числовые форматы вариант Число.

Вставка в ячейку текущих даты и времени

Вставка статический даты или времени

Текущая дата. Выделите ячейку и нажмите клавиши CTRL+;

Текущее время. Выделите ячейку и нажмите клавиши CTRL+SHIFT+;

Текущие дата и время. Выделите ячейку и нажмите клавиши CTRL+;, ПРОБЕЛ, а затем CTRL+SHIFT+;

Вставка обновляемых значений даты или времени

Для выполнения этой задачи используются функции СЕГОДНЯ и ТДАТА.

Пример листа

1

2
3

A	B
Формула	Описание (результат)
=СЕГОДНЯ()	Текущая дата (значения могут быть разными)
=ТДАТА()	Текущие дата и время (значения могут быть разными)

Примечание. Функции ТДАТА и СЕГОДНЯ меняют свое значение только при расчете листа или при выполнении макроса, содержащего эту функцию. Они не обновляются постоянно. В качестве значений даты и времени берутся значения системных часов компьютера.

Описание функций

СЕГОДНЯ

ТДАТА

Отображение дат в виде дней недели

Если требуется отсортировать ячейки по дате, измените их формат, чтобы отображались дни недели. Если ячейки требуется отсортировать или отфильтровать по дню недели независимо от даты, преобразуйте день недели в текстовый формат.

Форматирование ячеек для отображения дня недели

Выделите ячейки, содержащие даты, которые должны отображаться в виде дня недели.
В меню Формат выберите команду Ячейки, а затем откройте вкладку Число.
В списке Числовые форматы выберите вариант (все форматы), а в поле Тип введите дддд, чтобы отображались полные названия дней недели (понедельник, вторник и т. д.), либо ддд, чтобы отображались сокращенные названия дней недели (Пн, Вт, Ср и т. д.)

Преобразование дат в дни недели в текстовом формате

Для выполнения этой задачи используются функции ТЕКСТ и ДЕНЬНЕД.

Пример листа

1

2
3

A
Дата
19-фев-2007
3-янв-2008
Формула	Описание (результат)
=ТЕКСТ(ДЕНЬНЕД(A2);"дддд")	Вычисление дня недели для указанной даты и возврат его полного названия (понедельник)
=ТЕКСТ(ДЕНЬНЕД(A3);"ддд")	Вычисление дня недели для указанной даты и возврат его сокращенного названия (Пн)

Описание функций

ДЕНЬНЕД

ТЕКСТ